2008年08月20日星期三 [路日]　[旧版首页]

我不介意你恨我	啵一个	一首歌	真爱地图	相反词	来跳舞吧
爱在现实面前	雨霖铃	树叶的崇拜	日不落	完美故事	冰冰
快乐童话	嘟嘟娃娃	路太弯	差一点	让我看着你	客串情人

当前位置：首页 >> VFP专区 >> 将数字金额转换为人民币大写

在线连续剧免费播放: 五星大饭店奋斗血色浪漫家有儿女荣归大明天子连城诀

将数字金额转换为人民币大写

作者:　发布时间:2005-03-18 >>　 -收藏本页-

　　不用说，就是把数字转换成相对应的金额大写格式。

·添加到565key网摘 ·添加到vivi收藏 ·添加到网摘中国

·相关代码：

******************************************************
* 程序名称：CAMOUNT.PRG
* 编写日期：1997.1
* 运行平台：FoxPro 2.5 及以上版本
* 功    能：将数值型的数据转换为中文金额格式
* 调用方式：本程序以函数方式调用，
*             调用方式举例                         调用结果
*           1. lcPrcAmount = CAMOUNT(12.25)  变量lcPrcAmount 的值将为“一十二元二角五分”
*           2. ?CAMOUNT(12.25)                  屏幕上将显示 一十二元二角五分
*           3. WAIT WINDOW CAMOUNT(12.25)     WAIT 窗口中将显示一十二元二角五分
* 返 回 值：字符串型。
* 说    明：1. 该函数只能转换一千亿以下的数值型数据
*           2. 该函数处理时将小数点两位以后的数据截去（不作舍入处理）
* 程 序 员: 任明汉
******************************************************
LPARAMETER pnAmount
LOCAL lcTempStr, lcString, lcAmount, lnLen, lnCnt, nCnt
*--基本的错误处理
IF PARAMETERS() = 0
WAIT WINDOW "该函数需要一个数值型参数"
RETURN ""
ENDIF
IF TYPE("m.pnAmount ") &lt;&gt; "N"
   WAIT WINDOW "该函数只能转换数值型数据"
   RETURN ""
ENDIF
IF m.pnAmount  &gt; 99999999999.99
   WAIT WINDOW NOWAIT "只能转换千亿以内的数"
   RETURN ""
ENDIF
lcAmount = LTRIM(TRANSFORM(m.pnAmount,"999999999999.99"))
lnLen = LEN(m.lcAmount)
lcTempStr = ""
FOR lnCnt = m.lnLen TO 1 STEP -1
    lcTempStr = m.lcTempStr + SUBSTR(m.lcAmount,m.lnCnt,1)
ENDFOR
lcAmount = m.lcTempStr
*-- 转换角与分
lcTempStr = SUBSTR(m.lcAmount,2,1)+LEFT(m.lcAmount,1)
IF m.lcTempStr # "00"
   lcString = IIF(SUBSTR(m.lcAmount,2,1)="0" AND m.pnAmount &gt; 1,"零","")+;
              IIF(m.lcTempStr &gt; "09",SUBSTR("一角二角三角四角五角六角七角八角九角",;
              (VAL(LEFT(m.lcTempStr,1))-1)*4+1,4)+;
              Num2Text(VAL(RIGHT(m.lcTempStr,1))),;
              Num2Text(VAL(m.lcTempStr)))+;
              IIF(LEFT(m.lcAmount,1)#"0","分","")
ELSE
   lcString = IIF(m.pnAmount &gt; 0,"整","无金额")             
ENDIF
IF m.pnAmount &lt; 1
   RETURN m.lcString
ENDIF
* --  万以内
lcTempStr = ''
nCnt = IIF(m.lnLen &lt; 8,m.lnLen,7)
FOR lnCnt = m.nCnt TO 4 STEP -1
    IF SUBSTR(m.lcAmount,m.lnCnt,1)#"0"
       lcTempStr = IIF(m.lnLen &lt; m.lnCnt + 2 OR SUBSTR(m.lcAmount,m.lnCnt+1,1) # "0",;
       m.lcTempStr + Num2Text(VAL(SUBSTR(m.lcAmount,m.lnCnt,1))) +;
       IIF(m.lnCnt = 4,"",SUBSTR("十百千",2 * m.lnCnt-9,2)),;
       m.lcTempStr + "零" + Num2Text(VAL(SUBSTR(m.lcAmount,m.lnCnt,1))) +;
       IIF(m.lnCnt = 4,"",SUBSTR("十百千",2 * m.lnCnt-9,2)))
    ENDIF   
ENDFOR
lcString = m.lcTempStr + "元" + m.lcString
IF m.lnLen  &lt; 8
   RETURN m.lcString
ENDIF
* -- 亿以内
lcTempStr = ''
nCnt = IIF(m.lnLen &lt; 12,m.lnLen,11)
FOR m.lnCnt = m.nCnt TO 8 STEP -1
    IF SUBSTR(m.lcAmount,m.lnCnt,1)#"0"
       lcTempStr = IIF(m.lnLen &lt; m.lnCnt + 2 OR SUBSTR(m.lcAmount,m.lnCnt+1,1) # "0",;
       m.lcTempStr + Num2Text(VAL(SUBSTR(m.lcAmount,m.lnCnt,1))) +;
       IIF(m.lnCnt = 4,"",SUBSTR("十百千",2 * m.lnCnt-17,2)),;
       m.lcTempStr + "零" + Num2Text(VAL(SUBSTR(m.lcAmount,m.lnCnt,1))) +;
       IIF(m.lnCnt = 4,"",SUBSTR("十百千",2 * m.lnCnt-17,2)))
    ENDIF   
ENDFOR
lcString = TRIM(m.lcTempStr) + "万" + m.lcString
IF m.lnLen  &lt; 12
   RETURN m.lcString
ENDIF
* -- 千亿以内
lcTempStr = ''
m.nCnt = IIF(m.lnLen &lt; 16,m.lnLen,15)
FOR m.lnCnt = m.nCnt TO 12 STEP -1
    IF SUBSTR(m.lcAmount,m.lnCnt,1)#"0"
       lcTempStr = IIF(m.lnLen &lt; m.lnCnt + 2 OR SUBSTR(m.lcAmount,m.lnCnt+1,1) # "0",;
       m.lcTempStr + Num2Text(VAL(SUBSTR(m.lcAmount,m.lnCnt,1))) +;
       IIF(m.lnCnt = 4,"",SUBSTR("十百千",2 * m.lnCnt-25,2)),;
       m.lcTempStr + "零" + Num2Text(VAL(SUBSTR(m.lcAmount,m.lnCnt,1))) +;
       IIF(m.lnCnt = 4,"",SUBSTR("十百千",2 * m.lnCnt-25,2)))
    ENDIF   
ENDFOR
RETURN TRIM(m.lcTempStr) + "亿" + lcString 
******************************************************
* FUNCTION Num2Text
* 功能 ：数值型的 1-9 转换成 中文的 一至九
* 参数 ： 1-9 之间的整数
* 返回值： 中文的 一至九
* 说明：本函数非公共函数，故未做参数的有无、参数的数据类型及数据范围的检查
******************************************************
FUNCTION Num2Text
LPARAMETER lcDigit
RETURN IIF(m.lcDigit # 0,SUBSTR("一二三四五六七八九",2 * m.lcDigit-1,2),"")
*-- EOF OF CAMOUNT.PRG